filename egdata URL "http://www.stat.wmich.edu/naranjo/sas/nhanes.txt";

DATA one;
	INFILE egdata FIRSTOBS=3;
	INPUT gender $ age race $ 19-37 education $ 38-54 fam_inc poverty 
              weight height bmi sys_bp dias_bp cholest glucose;
	RUN;

/************************************************/
/*Quick summary statistics for quantitative data*/
/************************************************/

PROC MEANS DATA=one;
        VAR bmi sys_bp dias_bp cholest glucose;
        TITLE 'Summary Statistics using PROC MEANS';
	RUN;

/* Most PROCs allow a BY option, but data needs to be sorted first */
PROC SORT DATA=one; 
	BY gender;
	RUN;

PROC MEANS DATA=one;
        VAR bmi sys_bp dias_bp cholest glucose;
        TITLE 'Summary Statistics by gender';
	BY gender;
	RUN;

/*PROC TABULATE allows customized tables of summary statistics*/
PROC TABULATE DATA=one;
        CLASS education;
        VAR bmi;
        TABLE (education all), bmi*(n mean std);
        TITLE 'Table of Summary Statistics for BMI';
	RUN;

/************************************************/
/*Quick summary statistics for categorical data*/
/************************************************/

/*ONE-WAY FREQUENCY TABLE*/
/*  (See SAS Procedures Guide, Version 6, Third Edition, Chapter 20)*/
PROC FREQ DATA=one;
        tables education;
        TITLE 'One-Way Frequency Table By Education';
	RUN;

/*TWO-WAY FREQUENCY TABLE*/
PROC FREQ DATA=one;
        TABLES education*gender;
        TITLE 'Two-Way Frequency Table: Education by Gender';
	RUN;

QUIT;